Archives de mot-clé : Formula

Utiliser une validation de colonne pour valider le numéro de téléphone de vos contacts

Similairement à mon billet précédent, je vous propose une autre formule afin de valider le numéro de téléphone de vos contacts.

On peut ajouter une formule directement dans la colonne de type « Une seule ligne de texte » nommé « Téléphone mobile » :

Les fonctions utilisés dans la formule doivent être dans la même langue que votre site (Français dans ce cas) :

=SI(ESTVIDE([Téléphone mobile]);VRAI;
ET(
 ESTERREUR(TROUVE(";";[Téléphone mobile];1));
 ESTERREUR(TROUVE(".";[Téléphone mobile];1));
 ESTERREUR(TROUVE("p";[Téléphone mobile];1));
 ESTERREUR(TROUVE("#";[Téléphone mobile];1));
 ESTERREUR(TROUVE(",";[Téléphone mobile];1));
 ESTERREUR(TROUVE("(";[Téléphone mobile];1));
 ESTERREUR(TROUVE(")";[Téléphone mobile];1)))
)

La formule ci-haut n’est pas aussi restrictive qu’une expression régulière mais elle constitue tout de même un bon départ :

  • Ignore la validation si le champ est vide;
  • Ne doit pas contenir le caractère « ; »;
  • Ne doit pas contenir le caractère « . »;
  • Ne doit pas contenir le caractère « p »;
  • Ne doit pas contenir le caractère « # »;
  • Ne doit pas contenir le caractère « , »;
  • Ne doit pas contenir le caractère « ( »;
  • Ne doit pas contenir le caractère « ) »;

Par la suite, entrer le message d’erreur désiré et tester le tout :

ValidationTelephoneMsg

 

Utiliser une validation de colonne pour valider l’adresse courriel de vos contacts

Un des problèmes courant lorsqu’on met en place une liste de contact est que les données ne sont pas toujours uniformes et valides. Puisque certains contacts n’ont pas d’adresse courriel, on ne peut pas mettre ce champ obligatoire. Cependant, on peut ajouter une validation au niveau de la colonne.

On peut ajouter une formule directement dans la colonne de type « Une seule ligne de texte » nommé « Courrier électronique » :

ValidationColonne.PNG

Les fonctions utilisés dans la formule doivent être dans la même langue que votre site (Français dans ce cas) :

=SI(ESTVIDE([Courrier électronique]);VRAI;
ET(
ESTERREUR(TROUVE(" "; [Courrier électronique];1));
ESTERREUR(TROUVE(";"; [Courrier électronique];1));
ESTERREUR(TROUVE(".."; [Courrier électronique];1));
ESTERREUR(TROUVE(".@"; [Courrier électronique];1));
SI(ESTERREUR(TROUVE("@"; [Courrier électronique];2)); FAUX;
ET( ESTERREUR(TROUVE("@";[Courrier électronique]; TROUVE("@"; [Courrier électronique];2)+1));
SI(ESTERREUR(TROUVE("."; [Courrier électronique]; TROUVE("@"; [Courrier électronique];2)+2)); FAUX;
TROUVE("."; [Courrier électronique]; TROUVE("@"; [Courrier électronique];2)+2) < NBCAR([Courrier électronique])
)
)
)
)
)

La formule ci-haut n’est pas aussi restrictive qu’une expression régulière mais elle constitue tout de même un bon départ :

  • Ignore la validation si le champ est vide;
  • Ne doit pas contenir d’espace;
  • Ne doit pas contenir le caractère « ; »;
  • Ne doit pas contenir deux points consécutifs;
  • Ne doit pas contenir un point précédent le @;
  • Ne doit pas contenir de plusieurs @;
  • Ne dois pas commencer par un @;
  • Ne dois pas se terminer par un « . »;
  • Doit contenir au moins un « . » après le @;
  • Doit contenir au moins un caractère entre le « . » et le @.

Par la suite, entrer le message d’erreur désiré et tester le tout :

ValidationColonneInvalide